;Selective MT experiment for Imino-Imino correlations
;avance-version (17/08/18)
;homonuclear correlation via dipolar coupling 
;based on noesgpph
;dipolar coupling may be due to noe or chemical exchange.
;phase sensitive
;with gradient pulses in mixing time
;
;E. Kupce & R. Freeman, J. Magn. Reson. 162, 300-310 (2003)
;
;$CLASS=HighRes
;$DIM=2D
;$TYPE=
;$SUBTYPE=
;$COMMENT=
;
;Experiment Setup:
;(1) use had_pl au-program to get the peak list
;(2) execute the 'seq_sl' command
;(3) start the experiment
;(4) use proc_seq au-program for processing


#include <Avance.incl>
#include <Grad.incl>
#include <Delay.incl>


define list<shape> SPL=<$VALIST>
define list<frequency> f3_list=<$FQ3LIST>
define list<frequency> f3_zero={sfo hz, 0.0}

"p2=p1*2"
"cnst23=cnst23"
"TAU=d21-p50*cnst40"
;"TAU=39u"

"l3=0"

"acqt0=-p1*2/PI"


1 ze
4u pl12:f2
2 d1 do:f3 BLKGRAD 
1m iu3
4u do:f3
;20u fq=cnst18(bf ppm):f3 pl27:f3 
4u f3_list:f3
4u pl27:f3 
3 10u cpds7:f3 
  if "l3%2 > 0" 
  {
    (p34:SPL ph2):f1
  }
  else
  {
    (p34:sp44 ph2):f1
  }
  10u do:f3
  10u UNBLKGRAD
  p16:gp1
  d16 pl1:f1
  if "l3%2 > 0" 
  {
    (p50:sp50 ph1):f1
  }
  else
  {
    (p50:sp50 ph3):f1
  }  
  TAU
  p16:gp2
  d16
  (p51:sp51 ph2):f1
  d16 
  p16:gp2
  d21 pl26:f3
  ;d21 fq=cnst19(bf ppm):f3 pl26:f3
	4u f3_zero:f3
  10u BLKGRAD
  go=2 ph31 cpds3:f3
  1m ru3
  d1 do:f3 mc #0 to 2 F1QF(SPL.inc, f3_list.inc)
exit


ph1=0 2
ph2=0
ph3=2 0

ph31=0 2


;pl1 : f1 channel - power level for pulse (default) 
;pl26 : f3 channel - power level for decoupling during acquisition
;pl27 : f3 channel - power level for low power decoupling during imino encoding
;p1 : f1 channel -  90 degree high power pulse
;p2 : f1 channel - 180 degree high power pulse
;p16: homospoil/gradient pulse                       [1 msec] 
;p28: Saturation pulse duration
;p34: f1 channel - saturation pulse created by wvm
;d1 : relaxation delay; 1-5 * T1
;d16: delay for homospoil/gradient recovery
;d21 : as short as possible delay so TAU is positive, will depend on cnst55 
;TAU : d21 minus compensation for shaped pulse evolution
;cnst23: B1 field for Hadamard saturation encoding pulses
;cnst40: Correction for shaped pulse evolution e.g. 0.529 for PC9; 0.35 for sinc1
;cnst54: H(N) chemical shift (offset, in ppm)  e.g. 12.2 ppm (current default for RNA imino)
;cnst55: H(N) bandwidth (in ppm)               e.g. 5 ppm (current default for RNA imino)
;cpd3: decoupling according to sequence defined by cpdprg3: garp4
;pcpd3: f3 channel - 90 degree pulse for decoupling sequence during acquisition 
;cpd7: decoupling according to sequence defined by cpdprg7: garp4
;pcpd7: f3 channel - 90 degree pulse for very soft decoupling sequence during imino encoding (500 us)
;ns: 2 * n
;ds: 4
;td1: size of Hadamard matrix, power of 2 (> # of peaks);
;FnMODE: QF


;for z-only gradients (optional):
;gpz1: 40%

;use gradient files (optional):   
;gpnam1: SMSQ10.100



;WaveMaker shapes
;use 'wvm -a' command to create the necessary shape files
;sp50:wvm: pc5(cnst55 ppm, cnst54 ppm)
;sp51:wvm: reburp(cnst55 ppm, cnst54 ppm)
;sp44:wvm:SQsat2: cw_i(p28, -7 ppm; B1max = cnst23 Hz) ss = 5u 
;gp1:wvm:gwurst.100: wurst_g(5 G/cm, 1 ms)





;$Id: ht_noesygpph,v 1.2 2017/11/23 10:49:08 ber Exp $
